[サービスの状態を確認する]

Telnet サービスの状態を確認します。

【ソースコード】

[tips0187.vbs]
Option Explicit

Dim strQuery            ' サービス取得ＳＱＬ
Dim strServiceName      ' サービス名
Dim lngServiceCount     ' サービス数
Dim objServiceList      ' 対象のサービス一覧
Dim objServiceInfo      ' サービスの情報

strServiceName = "TlntSvr"
lngServiceCount = 0

strQuery = "SELECT * FROM Win32_Service" & _
            " WHERE Name = '" & strServiceName & "'"
Set objServiceList = GetObject("winmgmts:").ExecQuery(strQuery)
For Each objServiceInfo In objServiceList
    If objServiceInfo.State = "Running" Then
        WScript.Echo objServiceInfo.Name & "は開始しています。"
    ElseIf objServiceInfo.State = "Stopped" Then
        WScript.Echo objServiceInfo.Name & "は停止しています。"
    ElseIf objServiceInfo.State = "Paused" Then
        WScript.Echo objServiceInfo.Name & "は一時停止しています。"
    Else
        WScript.Echo objServiceInfo.Name & "の状態が分かりません。"
    End If
    lngServiceCount = lngServiceCount + 1
Next

If lngServiceCount = 0 Then
    WScript.Echo strServiceName & "サービスが見つかりませんでした。"
End If

Set objServiceList = Nothing

【実行結果】

C:\> cscript //NoLogo tips0187.vbs
TlntSvrは停止しています。