[ショートカットを作成する]

デスクトップ上に、メモ帳（notepad.exe）のショートカットを作成します。
ショートカットキーに Ctrl+Alt+N を割り当てています。
既に同名のファイルが存在する場合は上書きされます。

【ソースコード】

[tips0120.vbs]
Option Explicit
On Error Resume Next

Dim objWshShell     ' WshShell オブジェクト
Dim strDesktopPath  ' デスクトップのフォルダ名
Dim strWindowsPath  ' ウィンドウズのフォルダ名
Dim objShortcut     ' ショートカット情報

Set objWshShell = WScript.CreateObject("WScript.Shell")
If Err.Number = 0 Then
    strDesktopPath = objWshShell.SpecialFolders("Desktop")
    strWindowsPath = objWshShell.ExpandEnvironmentStrings("%WINDIR%")
    Set objShortcut = objWshShell.CreateShortcut(strDesktopPath & "\notepad.lnk")
    objShortcut.Description = "テストショートカット"
    objShortcut.HotKey = "CTRL+ALT+N"
    objShortcut.IconLocation = "notepad.exe,1"
    objShortcut.TargetPath = strWindowsPath & "\notepad.exe"
    objShortcut.WorkingDirectory = strWindowsPath
    objShortcut.Save

    If Err.Number = 0 Then
        WScript.Echo "ショートカットを作成しました。"
    Else
        WScript.Echo "エラー: " & Err.Description
    End If
Else
    WScript.Echo "エラー: " & Err.Description
End If

Set objShortcut = Nothing
Set objWshShell = Nothing

【実行結果】

C:\> cscript //NoLogo tips0120.vbs
ショートカットを作成しました。