[定数ファイルを（adovbs.inc）を読み込む]

C:\Program Files\Common Files\System\ado フォルダにある ADO の定数定義ファイル（adovbs.inc）を読み込みます。
C 言語の #include のイメージです。

【ソースコード】

[tips0138.vbs]
Option Explicit

Function IncludeAdoDefine()
    Dim blnRetCode      ' 戻り値
    Dim objFSO          ' FileSystemObject
    Dim strIncFile      ' 定数定義ファイル
    Dim objIncFile      ' 定数定義ファイル
    Dim strReadLine     ' ファイル読み込みバッファ

    On Error Resume Next
    blnRetCode = True

    Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
    If Err.Number = 0 Then
        strIncFile = "C:\Program Files\Common Files\System\ado\adovbs.inc"
        Set objIncFile = objFSO.OpenTextFile(strIncFile)
        If Err.Number = 0 Then
            Do While objIncFile.AtEndOfStream <> True
                strReadLine = Trim(objIncFile.ReadLine)
                ' コメント行などで無かったら読み込む
                If Left(strReadLine, 1) <> "'" And _
                    strReadLine <> "" And _
                    strReadLine <> "<%" And _
                    strReadLine <> "%>" _
                Then
                    ExecuteGlobal strReadLine
                End If
            Loop
            objIncFile.Close()
        Else
            WScript.Echo "エラー：" & Err.Description
            blnRetCode = False
        End If
    Else
        WScript.Echo "エラー：" & Err.Description
        blnRetCode = False
    End If

    Set objIncFile = Nothing
    Set objFSO = Nothing
    IncludeAdoDefine = blnRetCode
End Function

If IncludeAdoDefine() = True Then
    WScript.Echo "定義ファイルを読み込みました。"
End If

【実行結果】

C:\> cscript //NoLogo tips0138.vbs
定義ファイルを読み込みました。