[戻る，進む，中止ボタンを操作する]

InternetExplorer の戻る，進むボタンなどを操作します。
メニュー操作で標準入出力を使用していますので cscript.exe で実行してください。

【ソースコード】

[tips0156.vbs]
Option Explicit
On Error Resume Next

' メニュー表示関数
Function DispMenu()
    Dim lngSelNo    ' 選択番号
    On Error Resume Next

    WScript.Echo "★操作メニュー"
    WScript.Echo "　1. URL 指定"
    WScript.Echo "　2. 戻る"
    WScript.Echo "　3. 進む"
    WScript.Echo "　4. 中止"
    WScript.Echo "　5. 終了"
    WScript.StdOut.Write "番号を入力してください＞ "
    lngSelNo = CLng(WScript.StdIn.ReadLine)
    If lngSelNo < 1 And lngSelNo > 5 Then
        lngSelNo = 0
    End If

    DispMenu = lngSelNo
End Function

Dim objIE       ' IE オブジェクト

Set objIE = WScript.CreateObject("InternetExplorer.Application")
If Err.Number = 0 Then
    objIE.Visible = True

    Do While True
        Select Case DispMenu
        Case 1 ' URL 指定
            WScript.StdOut.Write "URL を入力してください＞ "
            objIE.Navigate WScript.StdIn.ReadLine
        Case 2 ' 戻る
            objIE.GoBack
        Case 3 ' 進む
            objIE.GoForward
        Case 4 ' 中止
            objIE.Stop
        Case 5 ' 終了
            objIE.Quit
            Exit Do
        End Select
    Loop
Else
    WScript.Echo "エラー：" & Err.Description
End If
Set objIE = Nothing

【実行結果】

C:\> cscript //NoLogo tips0156.vbs
★操作メニュー
　1. URL 指定
　2. 戻る
　3. 進む
　4. 中止
　5. 終了
番号を入力してください＞