[表示色を変更する]

背景色,文字色,リンク色を変更します。

【ソースコード】
[tips0163.vbs]
Option Explicit
On Error Resume Next

Dim strUrl          ' 表示するページ
Dim objIE           ' IE オブジェクト
Dim objDoc          ' ドキュメント情報
Dim objStyle        ' スタイル情報
Dim strBgColor      ' 背景色
Dim strFgColor      ' 文字色
Dim strLinkColor    ' リンク色

strUrl = "http://www.whitire.com/"
strBgColor = "#000000"      ' 黒
strFgColor = "#ff0000"      ' 赤
strLinkColor = "#00ff00"    ' 緑

Set objIE = WScript.CreateObject("InternetExplorer.Application")
If Err.Number = 0 Then
    objIE.Navigate strUrl
    objIE.Visible = True

    ' ページが取り込まれるまで待つ
    Do While objIE.busy
        WScript.Sleep(100)
    Loop
    Do While objIE.Document.readyState <> "complete"
        WScript.Sleep(100)
    Loop

    ' ドキュメント情報で設定
    Set objDoc = objIE.Document
    objDoc.bgColor = strBgColor
    objDoc.fgColor = strFgColor
    objDoc.linkColor = strLinkColor

    ' スタイル情報で設定
    Set objStyle = objDoc.Body.Style
    objStyle.backgroundColor = strBgColor
    objStyle.Color = strFgColor
    objDoc.LinkColor = strLinkColor
Else
    WScript.Echo "エラー:" & Err.Description
End If
Set objIE = Nothing