[常に新しいウィンドウを開く]

リンクをクリックしたときに、常に新しいウィンドウで開きます。

【ソースコード】

[tips0168.vbs]
Option Explicit
On Error Resume Next

' 終了通知関数
Sub Test_OnQuit()
    Set objIE = Nothing
    Set objShell = Nothing
    WScript.Quit
End Sub

' マウスクリック時の関数
Sub TestDocOnClick()
    Dim objEvent    ' イベント情報

    Set objEvent = objIE.Document.parentWindow.event
    If objEvent.srcElement.tagName = "A" Then
        WScript.Echo objEvent.srcElement.href & " を開きます。"
        objEvent.returnValue = False
        objShell.Run WScript.ScriptFullName & " " & objEvent.srcElement.href
    End If
End Sub

Sub Test_DocumentComplete(ByVal objDisp, ByVal strUrl)
    ' マウスクリック時の関数を登録
    Set objIE.Document.onClick = GetRef("TestDocOnClick")
End Sub

Dim strUrl          ' 表示するページ
Dim objIE           ' IE オブジェクト
Dim objShell        ' WshShell オブジェクト

If WScript.Arguments.Count > 0 Then
    strUrl = WScript.Arguments.Item(0)
Else
    strUrl = "about:blank"
End If

Set objShell = WScript.CreateObject("WScript.Shell")
If Err.Number = 0 Then
    Set objIE = WScript.CreateObject("InternetExplorer.Application", "Test_")
    If Err.Number = 0 Then
        objIE.Navigate strUrl
        objIE.Visible = True

        ' 無限ループ
        Do While True
            WScript.Sleep(500)
        Loop
    Else
        WScript.Echo "エラー：" & Err.Description
    End If
Else
    WScript.Echo "エラー：" & Err.Description
End If

【実行結果】

C:\> cscript //NoLogo tips0168.vbs
http://www.yahoo.co.jp/ を開きます。
http://www.yahoo.co.jp/r/dic を開きます。