[サービスを開始する]

Telnet サービスを開始します。

【ソースコード】

[tips0185.vbs]
Option Explicit

Dim strQuery            ' サービス取得ＳＱＬ
Dim strServiceName      ' サービス名
Dim lngServiceCount     ' サービス数
Dim objServiceList      ' 対象のサービス一覧
Dim objServiceInfo      ' サービスの情報
Dim lngRetCode          ' 戻り値

strServiceName = "TlntSvr"
lngServiceCount = 0

WScript.Echo "サービス：" & strServiceName
strQuery = "SELECT * FROM Win32_Service" & _
            " WHERE Name = '" & strServiceName & "'"
Set objServiceList = GetObject("winmgmts:").ExecQuery(strQuery)
For Each objServiceInfo In objServiceList
    lngRetCode = objServiceInfo.StartService()
    If lngRetCode = 0 Then
        WScript.Echo "　起動しました。"
    ElseIf lngRetCode = 10 Then
        WScript.Echo "　既に起動されています。"
    Else
        WScript.Echo "　起動できませんでした。"
    End If
    lngServiceCount = lngServiceCount + 1
Next

If lngServiceCount = 0 Then
    WScript.Echo "　サービスが見つかりませんでした。"
End If

Set objServiceList = Nothing

【実行結果】

C:\> cscript //NoLogo tips0185.vbs
サービス：TlntSvr
　起動しました。