[タスク削除]

登録されているタスクをすべて削除します。
AT コマンドで作成されたものだけが削除の対象になります。

【ソースコード】

[tips0201.vbs]
Option Explicit
On Error Resume Next

Dim strServerName   ' コンピュータ名
Dim objWMIService   ' ウィンドウズ管理サービス
Dim objSchTasks     ' タスク情報
Dim objTask         ' タスク情報
Dim objInstance     ' インスタンス
Dim lngRetCode      ' 戻り値
Dim lngJobId        ' ジョブ番号

strServerName = "localhost"
Set objWMIService = GetObject("winmgmts:" & _
    "{impersonationLevel=impersonate}!\\" & _
    strServerName & "\root\cimv2")
Set objSchTasks = _
    objWMIService.ExecQuery("select * from Win32_ScheduledJob")
For Each objTask In objSchTasks
    lngJobId = objTask.JobId
    Set objInstance = _
        objWMIService.Get("Win32_ScheduledJob.JobID=" & lngJobId)
    If Err.Number = 0 Then
        lngRetCode = objInstance.Delete
        If lngRetCode = 0 Then
            WScript.Echo "タスクを削除しました。" & _
                "(JobID=" & lngJobId & ")"
        Else
            WScript.Echo "タスクの削除に失敗しました。" & _
                "(" & lngRetCode & ")"
        End If
    Else
        WScript.Echo "インスタンスの取得に失敗しました。"
    End If
    Set objInstance = Nothing
Next

Set objSchTasks = Nothing
Set objWMIService = Nothing

【実行結果】

C:\> cscript //NoLogo tips0201.vbs
タスクを削除しました。(JobID=1)