[メール送信（GMail）]

Google の GMail でメールを送信します。
標準のポート（25番）を使って送信する場合、ユーザー認証は不要です。
SSL(smtpusessl) の設定はサーバーによって異なります。
SSL をサポートしていない場合は、False を設定してください。
ユーザー名とパスワード部分、送信先などを変更するのを忘れないように（笑）

【ソースコード】

[tips0203.vbs]
Option Explicit
On Error Resume Next

Dim strSchemas      ' フィールド名（ベース）
Dim strUserName     ' ユーザー名（認証が必要なとき）
Dim strPassword     ' パスワード（認証が必要なとき）
Dim strFrom         ' メール送信元
Dim strTo           ' メール宛先
Dim strCc           ' メール宛先
Dim strBcc          ' メール宛先
Dim strSubject      ' 件名
Dim strBody         ' 本文
Dim strServer       ' メールサーバー
Dim lngPortNo       ' ポート番号
Dim objMessage      ' メール送信オブジェクト

strSchemas = "http://schemas.microsoft.com/cdo/configuration/"
strUserName = "***@gmail.com"
strPassword = "*****"
strFrom = "***@gmail.com"
strTo = "tonton@whitire.com"
strCc = ""
strBcc = ""
strSubject = "件名"
strBody = "メール送信テスト" & vbCrLf & "vbCrLf で改行します。"
strServer = "smtp.gmail.com"
lngPortNo = 465

Set objMessage = CreateObject("CDO.Message")
If Err.Number = 0 Then
    ' 認証ありのとき
    If strUserName <> "" Then
        objMessage.Configuration.Fields.Item _
            (strSchemas & "sendusername") = strUserName
        objMessage.Configuration.Fields.Item _
            (strSchemas & "sendpassword") = strPassword
        objMessage.Configuration.Fields.Item _
            (strSchemas & "smtpauthenticate") = 1
        objMessage.Configuration.Fields.Item _
            (strSchemas & "smtpusessl") = True
    End If

    ' アドレス設定
    objMessage.From = strFrom
    objMessage.To = strTo
    If strCc <> "" Then
        objMessage.Cc = strCc
    End If
    If strBcc <> "" Then
        objMessage.Bcc = strBcc
    End If

    ' 件名／本文
    objMessage.Subject = strSubject
    objMessage.TextBody = strBody

    ' サーバー情報
    objMessage.Configuration.Fields.Item _
        (strSchemas & "sendusing") = 2
    objMessage.Configuration.Fields.Item _
        (strSchemas & "smtpserver") = strServer
    objMessage.Configuration.Fields.Item _
        (strSchemas & "smtpserverport") = lngPortNo

    ' 送信
    objMessage.Configuration.Fields.Update
    objMessage.Send
    If Err.Number = 0 Then
        WScript.Echo "メールを送信しました。"
    Else
        WScript.Echo "メールの送信に失敗しました。" & _
            "(" & Err.Description & ")"
    End If
Else
    WScript.Echo "エラー: " & Err.Description
    blnRetCode = False
End If
Set objMessage = Nothing

【実行結果】

C:\> cscript //NoLogo tips0203.vbs
メールを送信しました。