[ドライブ情報を取得する]

引数で指定されたドライブの情報を取得します。

【ソースコード】

[tips0075.vbs]
Option Explicit
On Error Resume Next

Dim objFSO      ' FileSystemObject
Dim objDrive    ' ドライブ情報
Dim strDrive    ' ドライブ名
Dim strType     ' ドライブ種類の文字列

strDrive = WScript.Arguments.Item(0)
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
If Err.Number = 0 Then
    strType = Array("Unknown", "Removable", "HDD", "Network", "CD-ROM", "RAM")
    WScript.Echo "ドライブ " & strDrive & " の情報"
    If objFSO.DriveExists(strDrive) Then
        Set objDrive = objFSO.GetDrive(strDrive)
        If objDrive.IsReady = True Then
            WScript.Echo "　ボリュームラベル：" & objDrive.VolumeName
            WScript.Echo "　種類：" & strType(objDrive.DriveType)
            WScript.Echo "　ファイルシステム：" & objDrive.FileSystem
            WScript.Echo "　容量：" & FormatNumber(objDrive.TotalSize, 0)
            WScript.Echo "　空き領域：" & FormatNumber(objDrive.FreeSpace, 0)
            WScript.Echo "　フォルダ：" & objDrive.Path
            WScript.Echo "　ルートフォルダ：" & objDrive.RootFolder
            WScript.Echo "　シリアルナンバー：" & Hex(objDrive.SerialNumber)
        Else
            WScript.Echo "　準備ができていません"
        End If
    Else
        WScript.Echo "　存在しません。"
    End If
Else
    WScript.Echo "エラー: " & Err.Description
End If

Set objDrive = Nothing
Set objFSO = Nothing

【実行結果】

C:\> cscript //NoLogo tips0075.vbs c
ドライブ c の情報
　ボリュームラベル：Windows
　種類：HDD
　ファイルシステム：NTFS
　容量：10,733,957,120
　空き領域：8,007,376,896
　フォルダ：C:
　ルートフォルダ：C:\
　シリアルナンバー：985C257E