[フォルダ情報を取得する]

システムフォルダの情報を取得しています。
プロパティウィンドウで表示されているような項目です。

【ソースコード】

[tips0076.vbs]
Option Explicit
On Error Resume Next

Dim objFSO          ' FileSystemObject
Dim objSysFolder    ' フォルダ名
Dim blnStatus       ' 属性

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
If Err.Number = 0 Then
    Set objSysFolder = objFSO.GetSpecialFolder(1)
    WScript.Echo "名前：" & objSysFolder.Name
    WScript.Echo "種類：" & objSysFolder.Type
    WScript.Echo "ドライブ名：" & objSysFolder.Drive
    WScript.Echo "パス名：" & objSysFolder.Path
    WScript.Echo "サイズ：" & FormatNumber(objSysFolder.Size, 0)
    WScript.Echo "作成日時：" & objSysFolder.DateCreated
    WScript.Echo "属性："
    blnStatus = (objSysFolder.Attributes And 1) <> 0
    WScript.Echo "　読み取り専用：" & blnStatus
    blnStatus = (objSysFolder.Attributes And 2) <> 0
    WScript.Echo "　隠しファイル：" & blnStatus
Else
    WScript.Echo "エラー: " & Err.Description
End If

Set objSysFolder = Nothing
Set objFSO = Nothing

【実行結果】

C:\> cscript //NoLogo tips0076.vbs
名前：system32
種類：ファイル フォルダ
ドライブ名：C:
パス名：C:\WINNT\system32
サイズ：614,371,161
作成日時：2004/09/28 23:11:48
属性：
　読み取り専用：False
　隠しファイル：False