[読み取り専用属性を解除する]

C:\Work\ フォルダにあるファイルの『読み取り専用属性』を解除します。

【ソースコード】

[tips0089.vbs]
Option Explicit
On Error Resume Next

Dim strFolder       ' フォルダ名
Dim objFSO          ' FileSystemObject
Dim objFolder       ' フォルダ名
Dim objFile         ' ファイル名

strFolder = "C:\Work"
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
If Err.Number = 0 Then
    Set objFolder = objFSO.GetFolder(strFolder)
    For Each objFile In objFolder.Files
        If objFile.Attributes And 1 Then
            WScript.Echo "　・" & objFile.Name & _
                            "：読み取り専用です。"
        Else
            WScript.Echo "　・" & objFile.Name & _
                            "：読み取り専用ではありません。"
        End If
        objFile.Attributes = objFile.Attributes And &HFE
    Next

    WScript.Echo strFolder & _
        " にあるファイルの『読み取り専用属性』を解除しました。"
Else
    WScript.Echo "エラー: " & Err.Description
End If

Set objFile = Nothing
Set objFolder = Nothing
Set objFSO = Nothing

【実行結果】

C:\> cscript //NoLogo tips0089.vbs
　・test.txt：読み取り専用です。
　・test.doc：読み取り専用ではありません。
C:\Work にあるファイルの『読み取り専用属性』を解除しました。