[項目を取得する]

Dictionary オブジェクトに登録されているキーと値を表示します。

【ソースコード】
[tips0090.vbs]
Option Explicit
On Error Resume Next

Dim objDic      ' Dictionary オブジェクト
Dim objKey      ' キー
Dim objItem     ' 値
Dim lngPrefNum  ' 都道府県数
Dim lngLoop     ' ループカウンタ
Dim lngSubLoop  ' ループカウンタ

Set objDic = CreateObject("Scripting.Dictionary")
If Err.Number = 0 Then
    objDic.Add "北海道・東北", Array("北海道", "宮城", "福島", "岩手", "青森", "山形", "秋田")
    objDic.Add "関東", Array("東京", "神奈川", "千葉", "埼玉", "群馬", "山梨", "茨城", "栃木")
    objDic.Add "信越・北陸", Array("新潟", "長野", "福井", "石川", "富山")
    objDic.Add "中部", Array("愛知", "静岡", "岐阜", "三重")
    objDic.Add "関西", Array("大阪", "滋賀", "京都", "兵庫", "奈良", "和歌山")
    objDic.Add "中国", Array("広島", "岡山", "山口", "島根", "鳥取")
    objDic.Add "四国", Array("高松", "愛媛", "徳島", "高知")
    objDic.Add "九州・沖縄", Array("福岡", "佐賀", "長崎", "大分", "熊本", "鹿児島", "宮崎", "沖縄")

    WScript.Echo "○キーの表示"
    objKey = objDic.Keys
    For lngLoop = 0 To objDic.Count - 1
        WScript.Echo objKey(lngLoop)
    Next

    WScript.Echo "○値の表示"
    objKey = objDic.Keys
    For lngLoop = 0 To objDic.Count - 1
        WScript.Echo objKey(lngLoop)
        objItem = objDic.Item(objKey(lngLoop))
        For lngSubLoop = 0 To UBound(objItem)
            WScript.Echo " " & objItem(lngSubLoop)
            lngPrefNum = lngPrefNum + 1
        Next
    Next

    WScript.Echo objDic.Count & " 地区 " & _
        lngPrefNum & " 都道府県が登録されています。"
Else
    WScript.Echo "エラー: " & Err.Description
End If

Set objDic = Nothing

【実行結果】
C:\> cscript //NoLogo tips0090.vbs
○キーの表示
北海道・東北
関東
信越・北陸
中部
関西
中国
四国
九州・沖縄
○値の表示
北海道・東北
 北海道
 宮城
〜〜〜 以下略 〜〜〜