[テーブルの更新日を取得する]

Microsoft Access に付属しているサンプルデータベース（Northwind.mdb）にある社員テーブルの作成日と更新日を取得します。

【ソースコード】

[tips0144.vbs]
Option Explicit
On Error Resume Next

Dim strDbName   ' データベース名
Dim objAdoCon   ' ADO 接続
Dim objCatalog  ' カタログ情報
Dim strTable    ' テーブル名

strDbName = "Northwind.mdb"
strTable = "社員"

Set objAdoCon = WScript.CreateObject("ADODB.Connection")
If Err.Number = 0 Then
    objAdoCon.ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=" & strDbName
    objAdoCon.Open

    Set objCatalog = WScript.CreateObject("ADOX.Catalog")
    If Err.Number = 0 Then
        WScript.Echo strTable & " テーブルの："
        Set objCatalog.ActiveConnection = objAdoCon
        WScript.Echo "　作成日：" & _
            objCatalog.Tables(strTable).DateCreated
        WScript.Echo "　更新日：" & _
            objCatalog.Tables(strTable).DateModified
    Else
        WScript.Echo "エラー：" & Err.Description
    End If
    objAdoCon.Close
Else
    WScript.Echo "エラー：" & Err.Description
End If

Set objCatalog = Nothing
Set objAdoCon = Nothing

【実行結果】

C:\> cscript //NoLogo tips0144.vbs
社員 テーブルの：
　作成日：1999/02/07 16:18:01
　更新日：1999/02/16 1:26:28