[フィールド名の一覧を取得する（SELECT 結果から）]

Microsoft Access に付属しているサンプルデータベース（Northwind.mdb）にある受注明細テーブルのフィールドを取得します。
定数定義ファイルの読み込み関数（IncludeAdoDefine）を使用しています。（ソースコードは省略します）

【ソースコード】

[tips0143.vbs]
Option Explicit
On Error Resume Next

Dim strDbName   ' データベース名
Dim blnRetCode  ' 戻り値
Dim objAdoCon   ' ADO 接続
Dim objAdoRset  ' ADO 選択行
Dim objFldValue ' フィールド情報
Dim strSqlStmt  ' SQL 文

strDbName = "Northwind.mdb"

' ADO 定数の読み込み
blnRetCode = IncludeAdoDefine()
If blnRetCode = True Then
    Set objAdoCon = WScript.CreateObject("ADODB.Connection")
    If Err.Number = 0 Then
        objAdoCon.ConnectionString = _
            "Provider=Microsoft.Jet.OLEDB.4.0;" & _
            "Data Source=" & strDbName
        objAdoCon.Open

        Set objAdoRset = WScript.CreateObject("ADODB.Recordset")
        strSqlStmt = "SELECT * FROM 受注明細"
        objAdoRset.Open strSqlStmt, objAdoCon, adOpenStatic
        If Err.Number = 0 Then
            WScript.Echo "受注明細 テーブルのフィールド："
            For Each objFldValue In objAdoRset.Fields
                WScript.Echo "　" & objFldValue.Name
            Next
            objAdoRset.Close
        Else
            WScript.Echo "エラー：" & Err.Description
        End If

        objAdoCon.Close
    Else
        WScript.Echo "エラー：" & Err.Description
    End If
    Set objAdoCon = Nothing
End If

【実行結果】

C:\> cscript //NoLogo tips0143.vbs
受注明細 テーブルのフィールド：
　受注コード
　商品コード
　単価
　数量
　割引