[フィールド名の一覧を取得する（テーブル定義から）]

Microsoft Access に付属しているサンプルデータベース（Northwind.mdb）にある受注明細テーブルのフィールドを取得します。

【ソースコード】

[tips0142.vbs]
Option Explicit
On Error Resume Next

Dim strDbName   ' データベース名
Dim objAdoCon   ' ADO 接続
Dim objCatalog  ' カタログ情報
Dim strTable    ' テーブル名
Dim objColumn   ' フィールド情報

strDbName = "Northwind.mdb"
strTable = "受注明細"

Set objAdoCon = WScript.CreateObject("ADODB.Connection")
If Err.Number = 0 Then
    objAdoCon.ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=" & strDbName
    objAdoCon.Open

    Set objCatalog = WScript.CreateObject("ADOX.Catalog")
    If Err.Number = 0 Then
        WScript.Echo strTable & " テーブルのフィールド："
        Set objCatalog.ActiveConnection = objAdoCon
        For Each objColumn In objCatalog.Tables(strTable).Columns
            WScript.Echo "　" & objColumn.Name
        Next
    Else
        WScript.Echo "エラー：" & Err.Description
    End If
    objAdoCon.Close
Else
    WScript.Echo "エラー：" & Err.Description
End If

Set objCatalog = Nothing
Set objAdoCon = Nothing

【実行結果】

C:\> cscript //NoLogo tips0142.vbs
受注明細 テーブルのフィールド：
　割引
　受注コード
　商品コード
　数量
　単価