[テーブル名の一覧を取得する]

Microsoft Access に付属しているサンプルデータベース（Northwind.mdb）にあるテーブルを取得します。
通常のテーブルだけ出力しています。

【ソースコード】

[tips0141.vbs]
Option Explicit
On Error Resume Next

Dim strDbName   ' データベース名
Dim objAdoCon   ' ADO 接続
Dim objCatalog  ' カタログ情報
Dim objTable    ' テーブル情報

strDbName = "Northwind.mdb"
Set objAdoCon = WScript.CreateObject("ADODB.Connection")
If Err.Number = 0 Then
    objAdoCon.ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=" & strDbName
    objAdoCon.Open

    Set objCatalog = WScript.CreateObject("ADOX.Catalog")
    If Err.Number = 0 Then
        WScript.Echo strDbName & " のテーブル："
        Set objCatalog.ActiveConnection = objAdoCon
        For Each objTable In objCatalog.Tables
            ' 通常のテーブルだったら出力する
            If Trim(objTable.Type) = "TABLE" Then
                WScript.Echo "　" & objTable.Name
            End If
        Next
    Else
        WScript.Echo "エラー：" & Err.Description
    End If
    objAdoCon.Close
Else
    WScript.Echo "エラー：" & Err.Description
End If

Set objCatalog = Nothing
Set objAdoCon = Nothing

【実行結果】

C:\> cscript //NoLogo tips0141.vbs
Northwind.mdb のテーブル：
　運送会社
　仕入先
　社員
　受注
　受注明細
　商品
　商品区分
　都道府県
　得意先