[レコードを取得する]

Microsoft Access に付属しているサンプルデータベース（Northwind.mdb）にある運送会社テーブルのレコードを取得します。
定数定義ファイルの読み込み関数（IncludeAdoDefine）を使用しています。（ソースコードは省略します）

【ソースコード】

[tips0140.vbs]
Option Explicit
On Error Resume Next

Dim strDbName   ' データベース名
Dim blnRetCode  ' 戻り値
Dim objAdoCon   ' ADO 接続
Dim objAdoRset  ' ADO 選択行
Dim strSqlStmt  ' SQL 文

strDbName = "Northwind.mdb"

' ADO 定数の読み込み
blnRetCode = IncludeAdoDefine()
If blnRetCode = True Then
    Set objAdoCon = WScript.CreateObject("ADODB.Connection")
    If Err.Number = 0 Then
        objAdoCon.ConnectionString = _
            "Provider=Microsoft.Jet.OLEDB.4.0;" & _
            "Data Source=" & strDbName
        objAdoCon.Open

        Set objAdoRset = WScript.CreateObject("ADODB.Recordset")
        strSqlStmt = "SELECT * FROM 運送会社"
        objAdoRset.Open strSqlStmt, objAdoCon, adOpenStatic
        If Err.Number = 0 Then
            Do While objAdoRset.EOF <> True
                WScript.Echo objAdoRset("運送コード") & ": " & _
                    objAdoRset("運送会社") & " [" & _
                    objAdoRset("電話番号") & "]"
                objAdoRset.MoveNext
            Loop
            objAdoRset.Close
        Else
            WScript.Echo "エラー：" & Err.Description
        End If

        objAdoCon.Close
    Else
        WScript.Echo "エラー：" & Err.Description
    End If
    Set objAdoCon = Nothing
End If

【実行結果】

C:\> cscript //NoLogo tips0140.vbs
1: アカネコ [(03) 3955-98xx]
2: トマト [(03) 3681-31xx]
3: ペンギン [(03) 3566-99xx]