[Ｗｅｂサイトを停止する(IIS 5.0)]

Ｗｅｂサイトを停止します。
リモート操作する場合は、操作するＰＣにもＩＩＳのコンポーネント（共通コンポーネントだけあれば良いです）が必要です。

【ソースコード】

[tips0189.vbs]
Option Explicit
On Error Resume Next

Dim objService          ' サービス情報
Dim strServerName       ' サーバー名
Dim strServiceName      ' サービス名
Dim lngWebRootNum       ' サーバー番号
Dim strADSIObjName      ' サービス名
Dim blnRetCode          ' 戻り値

blnRetCode = True
strServerName = "localhost"
strServiceName = "既定の Web サイト"

WScript.Echo "サーバー：" & strServerName
WScript.Echo "Ｗｅｂサイト：" & strServiceName
Do While blnRetCode <> False
    lngWebRootNum = lngWebRootNum + 1
    Set objService = Nothing
    strADSIObjName = "IIS://" & strServerName & "/W3SVC/" & lngWebRootNum
    Set objService = GetObject(strADSIObjName)
    If Not objService Is Nothing Then
        If objService.ServerComment = strServiceName Then
            If objService.Status = 2 Then
                objService.Stop
                If objService.Status = 4 Then
                    WScript.Echo "　停止しました。"
                Else
                    WScript.Echo "　停止できませんでした。"
                End If
            Else
                WScript.Echo "　既に停止しています。"
            End If
            Exit Do
        End If
    Else
        WScript.Echo "　サービス名称が見つかりませんでした。"
        blnRetCode = False
    End If
Loop
Set objService = Nothing

【実行結果】

C:\> cscript //NoLogo tips0189.vbs
サーバー：localhost
Ｗｅｂサイト：既定の Web サイト
　停止しました。