[リダイレクトを設定する(IIS 5.0)]

ＩＩＳのリダイレクト先を設定（または変更）します。
リモート操作する場合は、操作するＰＣにもＩＩＳのコンポーネント（共通コンポーネントだけあれば良いです）が必要です。

【ソースコード】

[tips0190.vbs]
Option Explicit
On Error Resume Next

Dim objService          ' サービス情報
Dim strServerName       ' サーバー名
Dim strServiceName      ' サービス名
Dim lngWebRootNum       ' サーバー番号
Dim strADSIObjName      ' サービス名
Dim strRedirectUrl      ' リダイレクト先
Dim blnRetCode          ' 戻り値

blnRetCode = True
strServerName = "localhost"
strServiceName = "既定の Web サイト"
strRedirectUrl = "http://www.yahoo.co.jp/"

Do While blnRetCode <> False
    lngWebRootNum = lngWebRootNum + 1
    Set objService = Nothing
    strADSIObjName = "IIS://" & strServerName & "/W3SVC/" & lngWebRootNum
    Set objService = GetObject(strADSIObjName)
    If Not objService Is Nothing Then
        If objService.ServerComment = strServiceName Then
            WScript.Echo "サービス名称が見つかりました。(ID=" & lngWebRootNum & ")"
            Exit Do
        End If
    Else
        WScript.Echo "サービス名称が見つかりませんでした。"
        blnRetCode = False
    End If
Loop
Set objService = Nothing

If blnRetCode = True Then
    strADSIObjName = strADSIObjName & "/ROOT"
    Set objService = GetObject(strADSIObjName)
    If Not objService Is Nothing Then
        objService.HttpRedirect = strRedirectUrl & ", EXACT_DESTINATION"
        WScript.Echo "リダイレクトを設定しました(" & strServiceName & ")(" & strRedirectUrl & ")"
        objService.SetInfo
        Set objService = Nothing
    Else
        WScript.Echo "サービスに接続できませんでした(" & strADSIObjName & ")"
    End If
End If

【実行結果】

C:\> cscript //NoLogo tips0190.vbs
サービス名称が見つかりました。(ID=1)
リダイレクトを設定しました(既定の Web サイト)(http://www.yahoo.co.jp/)